Voicent Gateway SDK Reference Table of Content << Previous >> Next

Voicent Gateway Tcl/Tk Simple Interface

The Voicent Tcl/Tk Simple Interface class contains the following functions.

Since all these functions are implemented as a HTTP client communicating directly with Voicent Gateway, they can be run on any machine that has a connection to the host running the gateway. The Tcl/Tk interface source code is included at the end of this section.

This Tcl/Tk Simple Interface is developed based on Voicent Gateway Simple Outbound Call Interface.

Work with Interactive Applications

For many applications, it is desirable to get responses from callees in addition to deliver a message. The interaction can be implemented by using the low level gateway VoiceXML interface. However, using the low level API is a time consuming and error prone task. A better solution is to utilize Voicent IVR Studio to create an interactive application, and use the extended Simple Call Interface to trigger a phone call.

SYNOPSIS

callText phoneno text selfdelete gateway

DESCRIPTION

Make a phone call and play the specified text message. The text message is convert to voice by Voicent Gateway's text-to-speech engine.
 
The options are:
 
phoneno The phone number to call
text The message for the phone call
selfdelete Ask the gateway to automatically delete the call request after the call is made if it is set to '1'
gateway Installed Voicent Gateway. Defaults to 'http://localhost:8155'

The return value is the call request id <reqId>.

EXAMPLE

callText "123-4567" "Hello, how are you doing" "1"

Make a call to phone number '123-4567' and say 'Hello, how are you doing'. Since the selfdelete bit is set, the call request record in the gateway will be removed automatically after the call.
 
set reqId [callText "123-4567" "Hello, how are you" "0")]
 
Make a call to phone number '123-4567' and say 'Hello, how are you'. Since the selfdelete bit is not set, the call request record in the gateway will not be removed after the call. You can then use callStatus to get the call status, or use callRemove to remove the call record.
 

SYNOPSIS

callAudio phoneno audiofile selfdelete gateway

DESCRIPTION

Make a phone call and play the specified audio message.
 
The options are:
 
phoneno The phone number to call
audiofile The audio message for the phone call. The format must be PCM 16bit, 8KHz, mono wave file. The audio file must be on the same host as Voicent Gateway.
selfdelete Ask the gateway to automatically delete the call request after the call is made if it is set to '1'
gateway Installed Voicent Gateway. Defaults to 'http://localhost:8155'

The return value is the call request id <reqId>.

EXAMPLE

callAudio "123-4567" "C:\my audios\hello.wav" "1"

Make a call to phone number '123-4567' and play the hello.wav file. Since the selfdelete bit is set, the call request record in the gateway will be removed automatically after the call.
 
callAudio "123-4567" "C:\my audios\hello.wav" "0"
 
Make a call to phone number '123-4567' and play the hello.wav file. Since the selfdelete bit is not set, the call request record in the gateway will not be removed after the call. You can then use callStatus to get the call status, or use callRemove to remove the call record.
 
 

SYNOPSIS

callStatus reqId gateway

DESCRIPTION

Check the call status of the call with <reqId>. If the call is made, the return value is 'Call Made', or if the call is failed, the return value is 'Call Failed', or if the call will retry, the return value is "Call Will Retry", and for any other status, the return value is "".

Please note that an empty string is returned if the call is still in progress. You'll need to wait and then poll the status again.

EXAMPLE

set status [callStatus "11234035434"]
 

SYNOPSIS

callRemove reqId gateway

DESCRIPTION

Remove the call record of the call with reqId. If the call is not made yet, it will be removed also.

EXAMPLE

callRemove "11234035434"
 

SYNOPSIS

callTillConfirm vcastexe vocfile wavfile ccode gateway

DESCRIPTION

Keep calling a list of people until anyone enters the confirmation code. The message is the specified audio file. This is ideal for using it in a phone notification escalation process.

To use this feature, Voicent BroadcastByPhone Professional version has to be installed. This function is similar to the command line interface BroadcastByPhone has. But since the command cannot be invoke over a remote machine, this perl function uses the gateway to schedule an event, which in turn invokes the command on the gateway host.

The options are:

 
vcastexe The BroadcastByPhone program. It is usually 'C:\Program Files\Voicent\BroadcastByPhone\bin\vcast.exe' on the gateway host.
vocfile The BroadcastByPhone call list to use.
ccode The confirmation code use for the broadcast
wavfile The audio file to use for the broadcast
gateway Installed Voicent Gateway. Defaults to 'http://localhost:8155'

 

EXAMPLE

callTillConfirm
    "C:\Program Files\Voicent\BroadcastByPhone\bin\vcast.exe" \
    "C:\My calllist\escalation.voc" \
    "C:\My calllist\escalation.wav" \
    "911911"

This will invoke BroadcastByPhone program on the gateway host and start calling everyone one the call list defined in 'C:\My calllist\escalation.voc'. The audio message played is 'C:\My calllist\escalation.wav'. And as soon as anyone on the list enters the confirmation code '911911', the call will stop automatically.
 

Source Code


package require http


proc callText { phoneno text selfdelete {gateway "http://localhost:8155"} } {

  set url "$gateway/ocall/callreqHandler.jsp"

  set plist [list info "simple text call" \
                  phoneno $phoneno \
                  firstocc 10 \
                  txt $text \
                  selfdelete $selfdelete]
  set param [eval ::http::formatQuery $plist]

  set token [::http::geturl $url -query $param]
  set rcstr [::http::data $token]
  ::http::cleanup $token

  return [getReqId $rcstr]
}

proc callAudio {phoneno filename selfdelete {gateway "http://localhost:8155"}} {

  set url "$gateway/ocall/callreqHandler.jsp"

  set plist [list info "simple audio call" \
                  phoneno $phoneno \
                  firstocc 10 \
                  audiofile $filename \
                  selfdelete $selfdelete]
  set param [eval ::http::formatQuery $plist]

  set token [::http::geturl $url -query $param]
  set rcstr [::http::data $token]
  ::http::cleanup $token

  return [getReqId $rcstr]
}

proc callStatus {reqId {gateway "http://localhost:8155"}} {

  set url "$gateway/ocall/callstatusHandler.jsp"

  set plist [list reqid $reqId]
  set param [eval ::http::formatQuery $plist]

  set token [::http::geturl $url -query $param]
  set rcstr [::http::data $token]
  ::http::cleanup $token

  if { [string first "^made^" $rcstr] != -1 } {
    return "Call Made"
  }

  if { [string first "^failed^" $rcstr] != -1 } {
    return "Call Failed"
  }

  if { [string first "^retry^" $rcstr] != -1 } {
    return "Call Will Retry"
  }

  return ""
}

proc callRemove {reqId {gateway "http://localhost:8155"}} {

  set url "$gateway/ocall/callremoveHandler.jsp"

  set plist [list reqid $reqId]
  set param [eval ::http::formatQuery $plist]

  set token [::http::geturl $url -query $param]
  set rcstr [::http::data $token]
}

proc callTillConfirm { vcastexe vocfile wavfile ccode {gateway "http://localhost:8155"}} {

  set url "$gateway/ocall/callreqHandler.jsp"

  set cmdline "\"$vocfile\" -startnow -confirmcode $ccode -wavfile \"$wavfile\""
  set plist [list info "simple call till confirm" \
                  phoneno "1111111" \
                  firstocc 10 \
                  startexec $vcastexe \
                  cmdline $cmdline \
                  selfdelete "0"]
  set param [eval ::http::formatQuery $plist]

  set token [::http::geturl $url -query $param]
  set rcstr [::http::data $token]
  ::http::cleanup $token

  return [getReqId $rcstr]
}

proc getReqId { rcstr } {

  set index1 [string first "\[ReqId=" $rcstr]
  if { $index1 == -1 } {
    return ""
  }
  set rcstr [string range $rcstr [expr $index1 + 7] end]

  set index2 [string first "\]" $rcstr]
  if { $index2 == -1 } {
    return ""
  }

  return [string range $rcstr 0 [expr $index2 - 1]]
}

# Sample usage

# replace with your own number
set phoneno "1112222"

#set reqId [callText $phoneno "Hello, how are you" "1"]
#puts $reqId

#set reqId [callAudio $phoneno "C:/Program Files/Voicent/MyRecordings/sample_message.wav" "0"]
#puts $reqId

#while { 1 } {
# after 10000
# set status [callStatus $reqId]
# if { $status != "" } {
# puts $status
# break
# }
#}

#callRemove $reqId

#callTillConfirm "C:/Program #Files/Voicent/BroadcastByPhone/bin/vcast.exe" \
#"C:/temp/testctf.voc" \
#"C:/Program Files/Voicent/MyRecordings/sample_messages.wav" \
#"1234"

 
Developer Network Table of Content << Previous >> Next